dos で internet なページ

dosppp + d-mail + bobcat で とりあえず使える internet 環境の作成

dosppp

dosppp は dialup ppp の packet driver です（よね？）

今回は、ダイアル時に ktx(dos用の通信ソフト) を使用してダイアル処理を確実＆簡単にすませています。

それから、wattcp.cfg を RAM DISK（私の環境では f:）に作成して、フラッシュカードへの無駄な書き込みを抑えています。

ディレクトリ構成

D:\TERM\
  +-- KTX\
  |     +-- KTX.EXE
  |     +-- KTX.CFG
  |     +-- KTX.NET
  +-- DOSPPP\
  |     +-- EPPPD.EXE
  |     +-- TERMIN.COM
  |     +-- PPPDRC.CFG
  |     +-- MYISP.DAT
  +-- DIALER.BAT

KTX の設定

KTX.NET に追加する

;---------------------------------------------------------------------------
#HT-NET21           ;ネット名 頭に#を付ける max32
rsparam     N81     ;通信条件 max9
baudrate    115200      ;ボーレート
xflow       off     ;XON/XOFF フロー制御
rflow       on      ;  RS/CS  フロー制御
bplus_auto  off     ;Bplus  自動起動
zmodem_auto off     ;Zmodem 自動起動
esccut      off     ;エスケープシーケンスのログファイル出力カット
useeuc      off     ;EUC使用
usejis      off     ;JIS使用
initm       0       ;モデムへの初期化文字列番号
logfname            ;ログファイル名 max127
telno       ****-**-****    ;電話番号 max191
userid      ********    ;ＩＤ 16文字まで
password    ********    ;パスワード 16文字まで(先頭が$なら暗号化)
telmoney    0       ;電話料金表テーブル番号
autologin   [:]$I[:]$P*$e()   ;オートログイン文字列 79文字まで
downprot    0       ;ダウンロードプロトコル番号
upprot      0       ;アップロードプロトコル番号
senddelay   0       ;テキスト送信wait数
group       0       ;グループ番号
;---------------------------------------------------------------------------

**** となっている所は、あなたの user名や、password を設定してください。２行目の #HT-NET21 は、接続先のプロバイダ名を指定するとよいでしょう。

ここでのポイントは、 autologin の設定の $e() です。これは、[:]$I[:]$P で user と password を送信後に、KTX を終了する事を意味します。

KTX.CFG の変更

endER           off             ;(B) 終了時の回線切断

endER を off にして、終了時に回線を切断しないようにします。終了時に回線を切断してしまうと、KTX を使ってダイアルする意味がなくなります(笑)

通常の利用で 終了時に切断したい 場合は、別のディレクトリ（例えば、dospppと同じディレクトリとか）に PPP 専用の KTX 環境を作成するとかしてください。

テスト

ここまで設定できたら、テストしてみましょう。

dos prompt の状態で、

D:\TERM\KTX>KTX HT-NET21

と入力してみて、「ダイアル→接続→ID入力→PASSWORD入力→KTX終了」と実行されるかチェックします。KTX終了後に回線が接続されままであることを確認してください。確認したら手で切断するのを忘れずに(笑)

dosppp の設定

PPPDRC.CFG の設定

COM1
115200
modem
crtscts
asyncmap 0

COM PORT と DTE 速度は KTX と同じ設定にしてください。

PAP 認証を行う場合は、user と passwd を PPPDRC.CFG に追加する必要があります。

MYISP.DAT の作成

hostname=PalmTopPC110
netmask=***.***.***.***
nameserver=***.***.***.***
domainslist="ht-net21.ne.jp"
gateway=***.***.***.***
SOCKDELAY=200

接続するプロバイダの設定を記述してください。

バッチファイルの作成

DIALER.BATの作成

@echo off
rem ***************************************************
rem 各種設定
rem ***************************************************
    rem --------------------------------
    rem dosPPP が存在するディレクトリ
    rem --------------------------------
    SET dosppp=D:\TERM\DOSPPP

    rem --------------------------------
    rem wattcp.cfg を作成するディレクトリ
    rem --------------------------------
    SET wattcp.cfg=f:\tmp

    rem --------------------------------
    rem ダイアルコマンド
    rem --------------------------------
    SET DIALCMD=D:\TERM\KTX\KTX HT-NET21


rem ***************************************************
rem 指定判別
rem ***************************************************
    if "%1"=="" goto DIALER
    if "%1"=="h" goto HANGUP
    if "%1"=="H" goto HANGUP
    goto SYNTERR


rem ***************************************************
rem 切断
rem ***************************************************
:HANGUP
    DEL %wattcp.cfg%\wattcp.cfg>NUL
    SET wattcp.cfg=
    SET DIALER_STATUS=
    %dosppp%\TERMIN 0x60
    ECHO.
    GOTO END


rem ***************************************************
rem PPP 接続処理
rem ***************************************************
:DIALER
    rem --------------------------------
    rem 既に接続がされているかチェック
    rem --------------------------------
    if "%DIALER_STATUS%"=="connect" goto ISCON

    rem --------------------------------
    rem ダイアル
    rem --------------------------------
    %DIALCMD%

    rem --------------------------------
    rem dosppp の起動
    rem --------------------------------
    COPY %dosppp%\PPPDRC.CFG %wattcp.cfg%>NUL
    BU PUSHD %wattcp.cfg%
    IF EXIST IP-UP.BAT DEL IP-UP.BAT%>NUL
    %dosppp%\EPPPD -pap
    IF ERRORLEVEL 1 GOTO CONNERR
    IF NOT EXIST IP-UP.BAT GOTO CONNERR
    CALL IP-UP.BAT
    BU POPD

    rem --------------------------------
    rem IP ADDRESS 等の設定
    rem --------------------------------
    IF EXIST %wattcp.cfg%\WATTCP.CFG DEL %wattcp.cfg%\WATTCP.CFG>NUL
    COPY %dosppp%\MYISP.DAT %wattcp.cfg%\WATTCP.CFG>NUL
    ECHO my_ip=%MYIP%>>%wattcp.cfg%\WATTCP.CFG
    rem ECHO gateway=%REMIP% >>%wattcp.cfg%\WATTCP.CFG
    rem ECHO netmask=%NETMASK% >>%wattcp.cfg%\WATTCP.CFG

    rem --------------------------------
    rem 必要がないファイルを削除
    rem --------------------------------
    DEL %wattcp.cfg%\PPPDRC.CFG>NUL
    DEL %wattcp.cfg%\IP-UP.BAT>NUL

    rem --------------------------------
    rem 接続完了
    rem --------------------------------
    ECHO PPP接続完了
    SET DIALER_STATUS=connect
    GOTO END


rem ***************************************************
rem 接続失敗
rem ***************************************************
:CONNERR
    BU POPD
    ECHO PPP接続に失敗しました
    GOTO END


rem ***************************************************
rem すでに接続されている
rem ***************************************************
:ISCON
    ECHO 警告:既に接続中です。
    goto USAGE


rem ***************************************************
rem 指定エラー
rem ***************************************************
:SYNTERR
    ECHO オプション指定エラー
    goto USAGE


rem ***************************************************
rem USAGE
rem ***************************************************
:USAGE
    ECHO usage : DIALER {H}
    GOTO END


rem ***************************************************
rem 終了
rem ***************************************************
:END
    SET dosppp=
    SET DIALCMD=
    echo.

カレントディレクトリとドライブの変更に 清水 洋平(Paci)氏の BU を使用しています。

あとは最初の「各種設定」部分の設定を変えるだけで動作するはずです。

PAP 認証を行う場合は、%dosppp%\EPPPD -pap を %dosppp%\EPPPD へ変更する必要があります。

テスト

DIALER.BAT を実行して正常に接続されるかチェックします。正常に接続できると

Installed packet driver handler at vector 0x60.

と表示されるはずです。wattcp.cfg がちゃんと作成されているかどうかもチェックしてください。

それから、DIALER H と入力する事で切断ができます。

これで、internet に接続する環境が出来上がりました。

bobcat

bobcat には dos 版の lynx(text www browser) が入ってます。

ダウンロード

ディレクトリ構成

D:\TERM\
  +-- BOBCAT\
        +-- LYNX.EXE
        +-- LYNX.CFG
        +-- WATTCP.CFG
        +-- HOME.HTM
        +-- BOBC_HLP.HTM

LYNX.CFG

特に変更しなくても動きます。一通り読んでみて変更したいところを変更しましょう。

WATTCP.CFG

bobcat は lynx.exe と同じディレクトリの wattcp.cfg しか読み込んでくれません。wattcp.cfg を d:\term\bobcat\ にコピーする方法も考えられますが、d:\term\bobcat\wattcp.cfg に

include=f:\tmp\wattcp.cfg

と指定する事によって、f:\tmp\wattcp.cfg の内容を読み込むことができます。

HOME.HTM

HOME.HTM は起動時に表示される html です。

私は、ブックマークを html 化したものを使用しています。

起動方法

ppp接続後に、lynx.exe を実行するだけです。

d-mail

作成中（永遠に出来ないかも(^^;;）

[戻る]