model	"WAV(RIFF)ファイルを読み込んで、チャンクを解析する"
{
	// ファイルパス
	macro	dir,file,ext;
	pathsplit	$(pathname), dir,file,ext;

	// 手続き
	procedure	strings		siz,len
	{
		// 現在のファイルポインタ位置から、+sizバイトまでの間で、
		// 長さlen文字以上の印刷可能文字(0x20〜0x7e)を探して、表示する。
		// 表示したバイト数を変数stringsに返す。
		nvar	len=4;

		var		slen;
		macro	str;

		var		fpos;
		var		fpos_end;
		var		cmp;
		var		cchr;
		macro	schr;

		ftell	fin,fpos;
		fpos_end=fpos + siz;
		while (fpos<fpos_end)
		{
			fgetc	fin,cchr;
			if (cchr<0x20 | 0x7e<cchr)
			{
				strlen	slen=$(str);
				if (slen>=len)
				{
					gsub	"#","＃",str;
					fprint	fout," "$(str);
					strings=strings + slen;
				}
				slen=0;
				mlet	str="";
			}
			else
			{
				chrcat	str,cchr;
			}

			ftell	fin,fpos;
		}
		strlen	slen=$(str);
		if (slen>=len)
		{
			gsub	"#","＃",str;
			fprint	fout," "$(str);
			strings=strings + slen;
		}
	}

	procedure	indent
	{
		var		idx;
		idx=0;
		while (idx<n_ind)
		{
			fprint	fout,"	";
			idx=idx + 1;
		}
	}

	procedure	fget16	fin,$$dat
	{
		// ファイルfinから16ビットの数値を読み込んで、
		// 変数$(dat)にセットする。数値はリトルエンディアン。
		// EOFに到達すると、-1をセットする。
		var		dat2;
		fgetb	fin,$(dat);
		fgetb	fin,dat2;
		$(dat)=@(dat2<<8 + $(dat));
		if (dat2=EOF)
		{
			$(dat)=EOF;
		}
	}

	procedure	fget32	fin,$$dat
	{
		// ファイルfinから32ビットの数値を読み込んで、
		// 変数$(dat)にセットする。数値はリトルエンディアン。
		// EOFに到達すると、-1をセットする。
		var		dat2;
		fgetb	fin,$(dat);
		fgetb	fin,dat2;
		$(dat)=@(dat2<<8 + $(dat));
		fgetb	fin,dat2;
		$(dat)=@(dat2<<16 + $(dat));
		fgetb	fin,dat2;
		$(dat)=@(dat2<<24 + $(dat));
		if (dat2=EOF)
		{
			$(dat)=EOF;
		}
	}

	procedure	fgetid	fin,$$id_buf
	{
		// ファイルfinから、文字コード4バイト(チャンクID等)を
		// 読み込んで、マクロ$(id_buf)に格納する。
		// EOFに到達すると、空文字""をセットする。
		// 文字ではないところを読んで、4バイト全てが非印刷可能文字だった
		// 場合も、空文字が返ることに注意。
		mlet	$(id_buf)="";
		var		dat;
		fgetb	fin,dat;
		chrcat	$(id_buf),dat;
		fgetb	fin,dat;
		chrcat	$(id_buf),dat;
		fgetb	fin,dat;
		chrcat	$(id_buf),dat;
		fgetb	fin,dat;
		chrcat	$(id_buf),dat;
		if (dat=EOF)
		{
			mlet	$(id_buf)="";
		}
	}

	procedure	analyze_chunk	fin,chunk_siz
	{
		// ファイルfinの現在のファイルポインタから始めて、
		// +chunk_sizまでの間のチャンクを分析する。
		var		cmp;
		var		fpos;
		var		fpos_start;
		var		siz;
		macro	buf;

		n_ind=n_ind + 1;

		// 開始位置(ファイルポインタ)を調べる
		ftell	fin,fpos_start;

		// チャンクを解析する
		repeat
		{
			// チャンクIDを読み込む
			fgetid	fin,buf;
			// EOF?
			strcmp	cmp=$(buf),"";
			if (cmp=0)
			{
				break;
			}

			// チャンクサイズ
			fget32	fin,siz;

			// ファイルポインタを取得
			ftell	fin,fpos;

			// サブチャンクの解析
			strcmp	cmp=$(buf),"LIST";
			if (cmp=0)
			{
				// LISTチャンク
				macro	form_typ;
				fgetid	fin,form_typ;

				mlet	NUM_FORM="%08x";
				fprint	fout,"(#) ",fpos - 8;
				indent;
				fprint	fout,$(buf)" # "$(form_typ)$,,siz;

				analyze_chunk	 fin,siz - 4;
			}
			else
			{
				mlet	NUM_FORM="%08x";
				fprint	fout,"(#) ",fpos - 8;
				indent;
				fprint	fout,$(buf)" #"$,,siz;

				strcmp	cmp=$(buf),"JUNK";
				if (cmp=0)
				{
					// JUNKチャンク
					strings		siz;
					if (strings>0)
					{
						fprint	fout,$,;
					}
				}
				else
				{
				strcmp	cmp=$(buf),"fmt ";
				if (cmp=0)
				{
					// WAVファイルのfmtチャンク
					var		fmt;
					var		chn;
					var		spl;
					var		bps;
					var		alg;
					var		wid;
					fget16	fin,fmt;
					fget16	fin,chn;
					fget32	fin,spl;
					fget32	fin,bps;
					fget16	fin,alg;
					fget16	fin,wid;

					mlet	NUM_FORM="%g";
					fprint	fout,"	fmt=# chn=# spl=# Bps=# alg=# wid=#"$,,
							fmt,chn,spl,bps,alg,wid;
				}
				}
			}

			// ファイルポインタをsiz(偶数境界に切り上げ)だけ進める。
			fseek	fin,fpos + @((siz + 1)/2)*2;
		} until !(fpos + @((siz + 1)/2)*2<fpos_start + chunk_siz);

		n_ind=n_ind - 1;
	}

	procedure	analyze_riff
	{
		var		cmp;
		var		siz;
		var		n_ind;		// インデントの深さ
		macro	buf;

		// RIFF IDを読み込む
		fgetid	fin,buf;
		strcmp	cmp=$(buf),"RIFF";
		if (cmp=0)
		{
			// データサイズ
			fget32	fin,siz;
			// データタイプ
			fgetid	fin,buf;

			mlet	NUM_FORM="%08x";
			fprint	fout,"(#) ",0;
			indent;
			fprint	fout,"RIFF # "$(buf)$,,siz;

			analyze_chunk	fin,siz - 4;
		}
		else
		{
			// ERROR: RIFFファイルではない
			fprint	fout,"Not a RIFF file."$,;
			return;
		}
	}

	// WAV(RIFF)ファイルを問いあわせる
	var		rtn;
	macro	fpath;
	gui		openfile,rtn, "WAV(RIFF)ファイルを指定してください","",fpath;
	if (rtn=-1)
	{
		// Cancel
		leave;
	}

	// ファイルを開く
	var		fin;
	fopen	fin,$(fpath),"r";
	if (fin<0)
	{
		errmsg		"WAV(RIFF)ファイルが開けなかった";
		leave;
	}
	var		fout;
	fopen	fout,$(fpath)".txt","w";
	if (fout<0)
	{
		errmsg		"出力ファイルが開けなかった";
		leave;
	}

	// 解析
	analyze_riff;

	// ファイルを閉じる
	fclose	fin;
	fclose	fout;
}