Option Explicit
'アドレスの自動検出をします。
'アドレスをキーボードから入力すると、
'登録しているアドレスの中から自動的にアドレスを
'入力してくれます。

'ﾌﾗｸﾞです
Dim flgBS As Boolean

Private Sub Form_Load()
    Dim j As Long
    
    'ComboBoxにｱﾄﾞﾚｽを入れます
    With Combo1
        .AddItem "http://www.dstorm.co.jp/"
        .AddItem "http://www2e.biglobe.ne.jp/~s-hasei/"
        .AddItem "http://home.att.ne.jp/gold/naoki/indexjp.html"
        .AddItem "http://www.netthai.com/inet/"
        .AddItem "http://www.microsoft.com"
    End With
    
    'ListBoxは、ｱﾄﾞﾚｽを直接閲覧するためだけに使っています
    'ComboBoxの内容をListBoxにｺﾋﾟｰします
    For j = 0 To Combo1.ListCount - 1
        List1.AddItem Combo1.List(j)
    Next
    
End Sub

Private Sub Combo1_Change()
    Dim j As Long, lngSel As Long

    'BackSpace、Deleteｷｰが押されていれば
    'Changeｲﾍﾞﾝﾄ内を実行しません
    If flgBS = True Or Combo1.Text = "" Then
        flgBS = False
        Exit Sub
    End If
    
    '一致するものを探します
    With Combo1
        For j = 0 To .ListCount - 1
            If InStr(1, .List(j), .Text, vbTextCompare) = 1 Then
                lngSel = .SelStart
                .Text = .List(j)
                .SelStart = lngSel
                .SelLength = Len(.Text) - lngSel
                Exit For
            End If
        Next
    End With
    
End Sub

Private Sub Combo1_KeyDown(KeyCode As Integer, Shift As Integer)

    If Not(Combo1.Text = "") And _
        (KeyCode = vbKeyBack Or KeyCode = vbKeyDelete) Then
        'ﾌﾗｸﾞを変えます
        flgBS = True
    End If

End Sub