;----------------------------------------------------------------
; ジョイスティック入力モジュール by MIA 2004.
;  使用に関する制限はありません。ご自由にお使いください。
;----------------------------------------------------------------

#include "loadlib.as"

#module "joy"

#deffunc joyGetPosEx val, int
	if jgpex=0 {
		ll_libload hwinmm, "winmm"
		ll_getproc jgpex, "joyGetPosEx", hwinmm
	}
	mref stt, 64 : mref joy, 16 : mref port, 1
	joy = 52, 255 : prm = port
	ll_getptr joy : ll_ret prm.1
	ll_callfunc prm, 2, jgpex : ll_ret stt
return

#global


;----------------------------------------------------------------
; サンプルコード
;----------------------------------------------------------------

;----------------------------------------------------------------
; joyGetPosEx data, ポート番号
;   stat = 0 であれば入力は正常です。
;	data.0 = 常に 52  が入ります
;	data.1 = 常に 255 が入ります
;	data.2 = 第 1 軸の状態（普通のジョイスティックの X 軸）
;	data.3 = 第 2 軸の状態（普通のジョイスティックの Y 軸）
;	data.4 = 第 3 軸の状態（スロットル等）
;	data.5 = 第 4 軸の状態
;	data.6 = 第 5 軸の状態
;	data.7 = 第 6 軸の状態
;	data.8 = ボタンの状態（最大32ボタン）
;	data.9 = 同時に押されているボタンの数
;	data.10 = POV スイッチの状態
;	data.11 = 予備情報1
;	data.12 = 予備情報2
;----------------------------------------------------------------

	repeat
		redraw 0
		palcolor 255 : boxf : palcolor 0
		joyGetPosEx data, 0
		pos 0,0 : mes "stat = " + stat
		repeat 13 : mes data.cnt : loop
		redraw 1 : await 30
	loop