'セル移動を制御するサンプルマクロ2

'MakeSheet2を実行してサンプルシートを作成してください。

Option Explicit

Sub MakeSheet2()
    Worksheets.Add
    With Range("A1")
        .Value = "Enterキーでセル移動するサンプルシート"
        With .Font
            .ColorIndex = 5
            .Bold = True
        End With
    End With
    Range("A2").Value = _
        "シート保護をすると、Tabキーで非保護セルを移動することができます。"
    Range("A3").Value = _
        "このシートではマクロを使い、Enterキーの動作をTabキーのものに置き換えています。"
    Range("A5").Value = "項目1"
    Range("C5").Value = "項目2"
    Range("A7").Value = "項目3"
    Range("C7").Value = "項目4"
    Range("A9").Value = "項目5"
    Range("C9").Value = "項目6"
    With Range("B5,D5,B7,D7,B9,D9")
        .BorderAround Weight:=xlThick, ColorIndex:=14
        .Locked = False
    End With
    Range("B5").Select
    MyOnSheetActivate2_On
    ActiveSheet.Protect , True, True, True
End Sub

'アクティブシートに自動実行マクロを登録するマクロ
Sub MyOnSheetActivate2_On()
    ActiveSheet.OnSheetActivate = "MyOnSheetActivate2"
    ActiveSheet.OnSheetDeactivate = "MyOnSheetDeactivate2"
    MyOnSheetActivate2
End Sub

'アクティブシートの自動実行マクロを解除するマクロ
Sub MyOnSheetActivate2_Off()
    ActiveSheet.OnSheetActivate = ""
    ActiveSheet.OnSheetDeactivate = ""
    MyOnSheetDeactivate2
End Sub

'キーの割り当てをするマクロ（自動実行マクロ）
Sub MyOnSheetActivate2()
    Application.OnKey "{ENTER}", "MyOnKeyEnter2"
    Application.OnKey "{RETURN}", "MyOnKeyEnter2"
    Application.OnKey "+{ENTER}", "MyOnKeyShiftEnter2"
    Application.OnKey "+{RETURN}", "MyOnKeyShiftEnter2"
End Sub

'キーの割り当てを解除するマクロ（自動実行マクロ）
Sub MyOnSheetDeactivate2()
    Application.OnKey "{ENTER}"
    Application.OnKey "{RETURN}"
    Application.OnKey "+{ENTER}"
    Application.OnKey "+{RETURN}"
End Sub

'Enterで起動するマクロ
Sub MyOnKeyEnter2()
    ActiveCell.Next.Activate
End Sub

'Shift+Enterで起動するマクロ
Sub MyOnKeyShiftEnter2()
    ActiveCell.Previous.Activate
End Sub