'文字列の数字部分をフォーマットする関数

'使用例

'数字部分を2桁にします。B列には 01、01-02、01-10 が表示されます。
'     A            B
'1  1      =FormatNum(A1,"00")
'2  1-2    =FormatNum(A2,"00")
'3  1-10   =FormatNum(A3,"00")

'半角数字対応なので､全角数字の場合は = FormatNum(Asc(A1), "00")
'のように､半角に変換して渡してください｡

Option Explicit

Function FormatNum(string1 As String, sFormat As String) As String
    Dim sNumber As String, sChar As String, sResult As String
    Dim i As Integer

    sResult = ""
    sNumber = ""
    For i = 1 To Len(string1)
        sChar = Mid$(string1, i, 1)
        Select Case sChar
            Case "0" To "9"
                sNumber = sNumber & sChar
            Case Else
                If Len(sNumber) <> 0 Then
                    sResult = sResult & Format$(CInt(sNumber), sFormat)
                    sNumber = ""
                End If
                sResult = sResult & sChar
        End Select
    Next
    If Len(sNumber) <> 0 Then
        sResult = sResult & Format$(CInt(sNumber), sFormat)
    End If
    FormatNum = sResult
End Function