'HTML ソースファイルを開くマクロ

Sub HTMLOpen()
    Dim vFileName As Variant
    Dim hFile As Long
    Dim oSheet As Worksheet
    Dim sBuffer As String
    Dim iRow As Long

    On Error GoTo ErrorHandler
    vFileName = Application.GetOpenFilename( _
        StrConv("HTML ドキュメント (*.ht*),*.ht*," & _
        "すべてのファイル (*.*),*.*", vbNarrow))
    If VarType(vFileName) <> vbString Then Exit Sub

    Application.ScreenUpdating = False

    hFile = FreeFile()
    Open vFileName For Input As #hFile

    Set oSheet = Workbooks.Add(xlWorksheet).Worksheets(1)
    oSheet.Columns(1).NumberFormat = "@"

    iRow = 0
    Do Until EOF(hFile)
        Line Input #hFile, sBuffer
        iRow = iRow + 1
        oSheet.Cells(iRow, 1).Value = sBuffer
    Loop
    Close #hFile
    hFile = 0

    oSheet.Columns(1).ClearFormats

    Application.ScreenUpdating = True

    Exit Sub

ErrorHandler:
    Application.ScreenUpdating = True
    MsgBox Error(Err) & " (" & CStr(Err) & ")", vbExclamation
    If hFile <> 0 Then Close #hFile
    Exit Sub
End Sub