[一覧] [入門編1] [入門編2] [入門編3] [実践編] [トラブル編]

オブジェクトについて

オブジェクトってなんですか？

オブジェクトは「物（もの）」という意味です。ワークシートやコマンドボタンなどのたくさんの種類のオブジェクトがあります。

オブジェクトの中にはデータとそれを操作するためのコマンドが入っています。このコマンドをVBAでは「メソッド」「プロパティ」と呼びます。プログラムでオブジェクトを操作するということは、「XXXXオブジェクトのXXXXメソッドを実行する」「XXXXオブジェクトのXXXXプロパティに値を設定する」といったことになります。

例えば、Sheet1というワークシートを選択するには、「Sheet1オブジェクトのSelectメソッドを実行」します。Sheet1の名前を変更するには、「Sheet1オブジェクトのNameプロパティに値を設定」します。

メソッドとプロパティってどこが違うの？

どちらもオブジェクトの内部にあるコマンドのようなもので、目的や役割に大きな違いはありません。使い方が異なります。メソッドは実行するもの、プロパティは値を設定したり取得したりするものです。特に、プロパティには値を設定できますが、メソッドには値を設定できません。

例えば、MyObjectというオブジェクトにMyMethodというメソッドとMyPropertyというプロパティがあるとき、MyObject.MyProperty = 100 という使い方はできますが、MyObject.MyMethod = 100 という使い方はできません。

クラスとインスタンスってなんですか？

クラスはオブジェクトの種類です。ワークシートクラスやコマンドボタンクラスなどのたくさんのクラスがあります。

インスタンスはオブジェクトの「実体」という意味です。オブジェクトのインスタンスはオブジェクトのクラスの定義（設計図）に基づいて作成されます。

例えば、Excelにはワークシートクラスの定義があり、それに基づいてSheet1というインスタンスが作成されます。

オブジェクトへの参照ってなんですか？

オブジェクトのインスタンスを識別するための内部的な番号のようなものです。プログラムの中では、オブジェクトへの参照を使ってオブジェクトのインスタンスを指定します。しかし、内部的に動的に決まる番号ですので、プログラムの中に直接、例えば「12番のオブジェクト」と書いても無意味です。

では、どうやってオブジェクトへの参照を取得するかと言うと、関連するメソッドやプロパティを使います。例えば、A1:C3のセル範囲のオブジェクトへの参照を取得するには Range("A1:C3") などとします。Rangeプロパティ（Excel5.0/95ではRangeメソッド）は対象オブジェクトを省略するとApplicationオブジェクトのプロパティとして解釈され、アクティブシート上の、指定されたRangeオブジェクトへの参照を返します。

オブジェクトへの参照は、その中身を直接見ることはできませんが、変数に格納し、オブジェクトへの参照を返すプロパティやメソッドの代わりに使用することができます。オブジェクトへの参照を変数に格納するにはSetステートメントを使います。
例えば、アクティブシートのA1:C3のRangeオブジェクトへの参照をobjという変数に格納するには、Set obj = Range("A1:C3") とします。このようにすると、Range("A1:C3").Clear の代わりに、obj.Clearとすることができます。

コレクションってなんですか？

同じ種類のオブジェクトのインスタンスの集まりです。
例えば、あるブックのワークシートの集まりを「ワークシートコレクション」とか「Worksheetsコレクションオブジェクト」といいます。コレクションもオブジェクトとして扱います。ほとんどのコレクションの名前はオブジェクトの名前の複数形になっています。

コレクションはオブジェクトへの参照を取得するときによく使います。例えば、アクティブブックのSheet1というワークシートのオブジェクト参照を取得するには、「アクティブブックのワークシートコレクションの中の、Sheet1という名前のシート」という指定をします。

コードでは ActiveWorkbook.Worksheets.Item("Sheet1") と書きます。
「ActiveWorkbook.Worksheets」の部分が「アクティブブックのワークシートコレクション」オブジェクトへの参照を返します。「.Item("Sheet1")」が「コレクションの中の、Sheet1という名前のシート」のオブジェクトへの参照を返します。

このItemプロパティ（Excel5.0/95ではItemメソッド）は、Worksheetsコレクションオブジェクトの既定のプロパティであるため、省略して、ActiveWorkbook.Worksheets("Sheet1") と書くことができます。

Itemには名前の他にインデックス番号を指定することもできます。例えば、左から2番目のワークシートを指定するには、ActiveWorkbook.Worksheets(2) とします。

コレクションには必ずCountプロパティがあります。アクティブブックのワークシートの数を取得するには、ActiveWorkbook.Worksheets.Count とします。

「Range("A1")」の「Range」は「Rangeオブジェクト」という意味ではないのですか？

違います。Rangeプロパティ（Excel5.0/95ではRangeメソッド）です。Rangeオブジェクトと関係が深いので同じ名前になっていますが、オブジェクト名ではありません。

RangeプロパティはApplicationオブジェクト、Worksheetオブジェクト、Rangeオブジェクトのプロパティです。Rangeオブジェクトへの参照を返すという点は同じですが、オブジェクトによって機能が異なります。オブジェクトが省略された場合は、ApplicationオブジェクトのRangeプロパティと解釈されます。（ただし、Excel5.0/95、Excel97の標準モジュールの場合です。）ApplicationオブジェクトのRangeプロパティは、アクティブシートの指定された範囲のRangeオブジェクトへの参照を返します。

「Application.ScreenUpdating」の「Application」は「Applicationオブジェクト」という意味ではないのですか？

違います。Applicationプロパティです。Applicationオブジェクトと関係が深いので同じ名前になっていますが、オブジェクト名ではありません。

Applicationプロパティは多くのオブジェクトにあり、そのオブジェクトを管理するアプリケーションオブジェクトへの参照を返します。ExcelVBAの中でオブジェクトが省略された場合は、Applicationオブジェクト（ExcelVBAではExcelのことになります）のApplicationプロパティと解釈されます。ApplicationオブジェクトのApplicationプロパティはApplicationオブジェクトへの参照を返します。

Sheet1やUserForm1はクラスですか？インスタンスですか？(Excel97)

Sheet1というクラス、UserForm1というクラス、Sheet1というSheet1クラスのインスタンス、UserForm1というUserForm1クラスのインスタンスがあります。

ワークシートを追加すると、例えば、Sheet1というクラスと、クラス名と同名のSheet1というインスタンスが自動的に作成されます。Sheet1クラスは複数のインスタンスを作成することはできません。

UserForm1の場合もほぼ同様ですが、ユーザフォームを追加したとき、UserForm1というインスタンスは名前が割り当てられるだけで、作成はされません。実際に作成されるのは、マクロ実行時にロード（Load）されたときです。ロードにはLoadステートメントを使いますが、これを使わなくても、UserForm1という名前を使えば自動的にロードされます。UserForm1クラスは複数のインスタンスを作成することができます。

Excel97ではワークシートもVBプロジェクトの一部です。ワークシートを追加、削除、変更することはプロジェクトを変更することであり、プロジェクト全体が初期化されることもあるようです。

実行制御

Personal.xls（個人用マクロブック）ってなんですか？

マクロ記録の「記録先」オプションの設定により、自動的に作成されるファイルです。
以下の特徴があります。

通常のExcelファイルです。

自動起動フォルダ（XLStart）に作成され、Excel起動時に自動的に開かれます。なおExcel起動時に自動的に開かれるファイルの場合、マクロ警告のメッセージは表示されません。マクロを含むファイルが開かれていてもユーザは気が付かない可能性があります。

非表示のファイルとして作成されます。再表示するにはメニューの[ウィンドウ]-[ウィンドウ再表示]を使います。

Excelのマクロウィルスとして有名なLaroux（ラルー）が自動作成し、感染、潜伏するファイルです。Larouxには、Personal.xlsが既に存在する場合は感染に失敗するというバグ（？）がありました。現在のマクロウィルスには多数のバリエーションがあり、Personal.xls以外のファイルに潜伏するものもあります。

マクロで行った処理をアンドゥできますか？

できません。元に戻すためのマクロを自分で書く必要があります。

エラー発生時にマクロを終了するには？

エラートラップを設定しておくと、エラー発生時に任意のコード位置へジャンプすることができます。

アクティブシートに「集計結果」という名前を付けるサンプルです。すでに同じ名前のシートがあるとエラーが発生しますが、その場合はErrorHandlerというラベルへジャンプし、メッセージを表示してプロシージャを終了させます。

Sub Sample_SetSheetName()
    Dim sName As String

    sName = "集計結果"

    'エラートラップを設定します
    'エラーが発生するとErrorHandlerというラベルへジャンプします
    On Error GoTo ErrorHandler

    'シート名を変更します
    ActiveSheet.Name = sName

    'エラートラップを解除します
    On Error GoTo 0

    'エラー処理へ行かないように、処理の最後には
    '必ずExit Subを書きます
    Exit Sub

'エラー処理のラベル
ErrorHandler:

    'エラーメッセージの表示
    MsgBox sName & " は既にあります。", vbExclamation
    Exit Sub

End Sub

Worksheet_Changeプロシージャでセルの値を変更するとまたプロシージャが実行されてしまいます(Excel97)

Excel97ではマクロからの操作の場合もイベントが発生します。

EnableEventsプロパティを使い、イベントを発生しないようにできます。EnableEventsプロパティを使用する場合は、エラートラップ処理を行い、マクロ終了後に必ずイベントが有効になるようにします。これを行わないとそれ以降イベントプロシージャが起動しなくなってしまいます。

Private Sub Worksheet_Change(ByVal Target As Excel.Range)

    '(処理)

    On Error GoTo ErrorHandler
    Application.EnableEvents = False
    Target.Value = 0
    Application.EnableEvents = True
    Exit Sub

ErrorHandler:
    MsgBox Error(Err), vbExclamation
    Application.EnableEvents = True
End Sub

Excelの機能の利用

Excelの関数がVBAで使えません

Excelのワークシート関数はVBAの関数とはまったく別のものです。そのままでは使うことはできません。

Application.関数名 として使います。ただしすべての関数が使えるわけではありません。また、ワークシート関数のDATE()とVBA関数のDate()のように名前が同じで機能が異なるものもありますので、区別して使う必要があります。

パラメータにセル参照を指定するにはRangeオブジェクトへの参照を指定します。

    a = Application.Sum(ActiveSheet.Range("A2:A100"))

Application.WorksheetFunction.Match()がエラーになります(Excel97)

WorksheetFunctionを使う場合はエラートラップ処理をする必要があります。Excel97でもApplication.Match()は従来通りVariant型のエラー値を返します。Excel97のバグなのか仕様なのか知りません。WorksheetFunctionは使わない方が無難かも。

赤色のセルの個数をカウントするユーザー定義関数を作成しましたが、セルの色を変更しても再計算されません。

セル書式の変更時には自動再計算は行われません。Ctrl+Alt+F9で強制再計算させます。

ユーザー定義ワークシート関数でセルに値を入力したいのですが？

できません。ユーザー定義ワークシート関数では、セルに値を返す以外の処理はほとんど許されていません。使用できるメソッドやプロパティにも制限があります。

グラフをGIFファイルに保存するには？(Excel97)

ChartオブジェクトのExportメソッドを使います。JPEGファイルに保存することも可能です。

ActiveChart.Export "C:\My Documents\Chart1.gif"

プログラミング

数値を文字列にしたい（桁区切りのカンマを入れたりしたい）のですが

Format$関数を使います。

Array関数をマクロで使うには？

複数シートの選択をマクロ記録すると、次のようにArray関数が使用されます。

Sheets(Array("Sheet1", "Sheet2")).Select

しかし、選択したいシート数が決まっていない場合は、この方法は使えません。Array関数の代わりに通常の配列変数を使います。

Sub Sample_SheetsSelect()
    Dim sNameArray() As String

    '動的配列を割り当てます
    ReDim sNameArray(1 To 3)

    'シート名を設定します
    sNameArray(1) = "Sheet1"
    sNameArray(2) = "Sheet2"
    sNameArray(3) = "Sheet3"

    'Array関数の代わりに配列変数を指定します
    Sheets(sNameArray).Select
End Sub

SendKeys "^c" を実行してもコピーされません

Excelのシートに対してキー送信した場合、キー送信はその時点で行われますが、Excelがそれを受け取って処理するのは、そのマクロの実行が終了してからになります。

ユーザーフォームでコントロール配列を使えますか？

Excel97VBAにはVBのようなコントロール配列はありません。

コントロールの名前を利用して、 Me.Controls("TextBox" & i) のような参照方法は可能です。

複数のコントロールでイベントプロシージャを共有するには、クラスモジュールを利用します。

ユーザーフォームの[X]ボタンを消すには？

[X]ボタンを消すことはできませんが、QueryCloseイベントを使用して、ユーザー操作によるクローズをキャンセルすることができます。

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = vbFormControlMenu Then
        Cancel = True
    End If
End Sub

印刷

ページヘッダーに今日の日付を設定するには？

ページヘッダーには &[日付] (マクロでは &D )という記号を使って日付を設定することができます。しかし、この方法では自由に日付の形式を指定することはできません。独自の設定をするにはマクロを使う必要があります。PageSetupオブジェクトの LeftHeader、CenterHeader、RightHeader、LeftFooter、CenterFooter、RightFooter の各プロパティを使用します。

以下のサンプルでは、ページヘッダーに、アクティブブックのフルパス名、シート名、1月23日(月) の形式の日付、時刻を設定します。このマクロはシートを印刷する前に毎回実行する必要があります。

Sub Sample_SetPageHeader()
    With ActiveSheet.PageSetup
        .LeftHeader = _
            ActiveWorkbook.FullName & _
            "  &A  " & _
            Format$(Date, "m""月""d""日(""aaa"")""") & _
            "  &T"
        .CenterHeader = ""
        .RightHeader = ""
        .LeftFooter = ""
        .CenterFooter = "&P / &N"
        .RightFooter = ""
    End With
End Sub

印刷ページ数をあらかじめ知るには？

Excel4.0マクロ関数のGET.DOCUMENTを使って調べることができます。

Sub Test_PageCount()
    Dim iPageCount As Integer
    Sheets("Sheet1").Select
    iPageCount = Application.ExecuteExcel4Macro("GET.DOCUMENT(50)")
    MsgBox CStr(iPageCount)
End Sub

マイクロソフトサポート技術情報にはHPageBreaksとVPageBreaksを使う方法も紹介されていますが、この方法では、最終行または最終列にデータがある場合に正しい結果になりません。もしかしたらExcel97ではGET.DOCUMENT(50)が正しい結果を返さないのかもしれませんが、今のところそのような話は聞いていません。

ダイアログボックス

実行前に確認メッセージを表示するには？

MsgBoxを使ったサンプルです。ボタンの種類や組み合わせは、用意されているものだけを使用することができます。

Sub Sample_Alert()
    Dim iRet As Long

    'ダイアログボックスを表示し、押されたボタンの種類を変数に入れます
    iRet = MsgBox("処理を実行します。", vbOKCancel Or vbExclamation)

    'キャンセルボタンが押された場合は終了します
    If iRet = vbCancel Then
        MsgBox "キャンセルされました。", vbInformation
        Exit Sub
    End If

    'ここに処理を書きます


    '終了メッセージを表示します
    MsgBox "処理を実行しました。", vbInformation

End Sub

マクロの中でセル範囲を指定するには？

InputBoxメソッドのTypeパラメータに8を指定するとセル範囲を入力することができます。Rangeオブジェクトが返されるのでSetステートメントを使う必要があります。また、キャンセル時は必ずエラーになるので、エラートラップを行う必要があります。

Sub Sample_InputRange()
    Dim oRange As Range

    Set oRange = Nothing
    On Error Resume Next
    Set oRange = Application.InputBox( _
        prompt:="セル範囲を選択してください。", _
        Title:="セル範囲の選択", _
        Type:=8)
    On Error GoTo 0

    If oRange Is Nothing Then
        MsgBox "キャンセルされました。", vbInformation
        Exit Sub
    Else
        MsgBox oRange.Address(external:=True) & _
            " が選択されました。", vbInformation
    End If
End Sub

ファイル名をダイアログボックスから入力するには？

Application.GetOpenFilenameを使います。
GetOpenFilenameの戻り値は、ファイルのフルパス名、False（Boolean型）、ファイル名の配列（複数選択時）のいずれかです。キャンセルされたかどうかは、戻り値がBoolean型であるかどうかをVarType関数などで調べて判定します。（データ型を無視した比較は、GetOpenFilenameでは問題がないとしても、おすすめできる方法ではありません。）

同様のメソッドに、GetSaveAsFilenameがあります。

Sub Input_FileName()
    Dim vFileName As Variant
    Dim sDefaultPath As String

    'デフォルトパスの設定（必要に応じて）
    sDefaultPath = "C:\My Documents\"
    ChDrive sDefaultPath
    ChDir sDefaultPath

    'Excelファイル名の入力（単一選択）
    vFileName = Application.GetOpenFilename( _
        fileFilter:=StrConv("Microsoft Excel ファイル (*.x*),*.x*," & _
        "すべてのファイル (*.*),*.*", vbNarrow), filterIndex:=1, _
        MultiSelect:=False)

    'キャンセルされたかチェック
    If VarType(vFileName) = vbBoolean Then
        MsgBox "キャンセルされました。"
        Exit Sub
    End If

    MsgBox vFileName & " が選択されました。"
End Sub

Excel5.0/95ダイアログシート、フォームコントロール

ユーザ定義ダイアログボックスからPrintOutメソッドを実行するとエラーになります（Excel5.0/95）

ユーザ定義ダイアログボックスを表示した状態では印刷や印刷プレビューはできません。ダイアログボックスを閉じてから印刷し、必要ならまた表示するようにします。

ユーザ定義ダイアログボックスから別のダイアログボックスを表示させると「スタック領域が不足」のエラーが発生します（Excel5.0）

Excel5.0では、ユーザ定義ダイアログボックスを表示した状態で別のユーザ定義ダイアログボックスを表示すると、2、3のレベルでエラーになります。ダイアログボックスを閉じてから別のダイアログボックスを表示し、その後、必要ならまた表示するようにします。

ダイアログボックスのリストボックスなどのフォントを変更できますか？（Excel5.0/95）

できません。ラベルやボタンはテキストボックスで代用が可能です。

その他

モジュールを見られないようにしたいのですが

Excel5.0/95ではモジュールシートを選択して[編集]-[シート]-[表示しない]で非表示にできます。再表示はワークシートメニューでは[書式]-[シート]-[再表示]です。Visibleプロパティのヘルプも確認してください。再表示されたくない場合は[ツール]-[保護]-[ブック保護]を設定します。バックアップ管理、パスワード管理をしっかり行いましょう。

アドインの作成は、モジュールシートのメニューで[ツール]-[アドインの作成]です。

Excel97では Visual Basic Editor でプロジェクトを選択し、[ツール]-[VBAProjectのプロパティ]（VBAProjectは実際には選択したプロジェクト名になります）[保護]で [プロジェクトを表示用にロックする]をチェックしてパスワードを設定、ブックを保存して閉じます。バックアップ管理、パスワード管理をしっかり行いましょう。

アドインを作成するには、Excelのメニュー[ファイル]-[名前を付けて保存]で[ファイルの種類]にMicrosoft Excelアドイン(*.xla) を選択して保存します。

ただし、Excelの保護機能はユーザインタフェースの機能であり、機密保護の機能ではないことに注意してください。保護を解除したりアドインをブックに復元する方法は 実際には存在します。例えば、Excel97はExcel5.0/95で作成したモジュールの保護を解除します。同様に、Excel97で設定した保護が将来のバージョンで解除される可能性もあります。

Excel97にバージョンアップしようと思いますが、Excel95のマクロはそのまま使えますか？

使えるものもあれば、使えないものもあります。主な仕様変更についてはマイクロソフトのWebページに情報（マイクロソフトサポート技術情報）があります。仕様変更の詳細についてはマイクロソフトに問い合わせてみてください。

同様に、Excel97で作成したマクロが将来のバージョンでそのまま動作するとは限りません。

[戻る]