--PlugAtk、ChariAtack2のハンドラについて--
この二つのハンドラの大きな特徴は
「好きな効果音を鳴らせる」ということです(要Damdisp2)。
省略した際にはデフォルトの効果音である「Hit」が鳴ります。
ただし、上記にも書いてありますが
Damdisp2ハンドラが無いと全く意味を成しません。
ChariAtack2ハンドラもPlugAtkハンドラが無ければ意味がありません。
いずれにせよChariAtack2ハンドラが使いたければ
下記のハンドラを全て組み込む必要があります。
ちなみに組み込む際へのDamdisp2ハンドラへの変更は全くの皆無です。
入れておくだけで効果を発揮します。
使用方法はそれぞれのハンドラにある注釈を見てください。
このハンドラの使用は自己責任においてやってください。
なお、この元のハンドラの著作権はボードウゲーム作者の名取氏の物です。
　　　　　　　　　　　　　　　　　　　　　　　　　　2000.12.16　斬(破軍星)

on Damdisp2 gBn,dan,kouka --被攻撃画面効果改。
  play stop
  if kouka is not empty then
    play kouka
  else
    play hit
  end if
  put icon of cd btn gBn into plIcon
  set icon of cd btn gBn to "4010"
  wait 5
  set icon of cd btn gBn to plIcon
end Damdisp2

on PlugAtk dam,wid,bac,sta,mus,disp,wee,srr,kouka --汎用攻撃ルーチン。ダメージ、範囲、肉体攻撃？、スタン？、無差別？、範囲表示完了？、特定人無効？、特定人有効？,効果音
  global gBn,Res,Str,gGas,gLocs
  put "Fail" into Res
  get gBn
  delete char 1 to 2 of it
  put line it of gLocs into plLoc
  -- put (item 1 of plLoc)-(wid-1)&","&(item 2 of plLoc)-(wid-1)&","&(item 1 of plLoc)+(wid-1)&","&(item 2 of plLoc)+(wid-1) into NewArea
  if disp is empty then --オリジナル描画なしなら
    put empty into gGas
    if wid >= 2 then
      if wid > 26 then put cd fld "coverdata2" into cd fld "Cover" --全体攻撃
      else dispAtackArea item 1 of plLoc,item 2 of plLoc,wid --範囲攻撃
    else dispTouchArea item 1 of plLoc,item 2 of plLoc,gBn --接触攻撃
  end if
  if mus is empty then --敵だけ
    put 5*(3-(line 1 of cd fld "comchar"))-4 into Sti
    put 5*(3-(line 1 of cd fld "comchar")) into Eni
  else --無差別攻撃
    put 1 into Sti
    put 10 into Eni
  end if
  put cd fld "cover" into CM
  put empty into AtkedChar
  repeat with i=Sti to Eni
    if (item 2 of cd btn ("pl"&i))<=0 or ("pl"&i) is gBn then next repeat
    -- get loc of cd btn ("pl"&i)
    -- put LocToCharLoc(item 1 of it,item 2 of it) into cLoc
    put line i of gLocs into cLoc
    if char (item 1 of cLoc) of line (item 2 of cLoc) of CM is "a" then
      if srr is not empty then --特定キャラに有効なら
        if item 1 of cd btn ("pl"&i) is in srr then
          put (i) into line (number of lines of AtkedChar)+1 of AtkedChar
        end if
      else --特定キャラに無効、あるいは通常なら
        if item 1 of cd btn ("pl"&i) is not in wee then
          put (i) into line (number of lines of AtkedChar)+1 of AtkedChar
        end if
      end if
    end if
  end repeat
  if AtkedChar is not empty then
    put "Hit" into Res
    --実際に表示
    repeat with j=1 to (number of lines of AtkedChar)
      put line j of AtkedChar into i
      Damdisp2 ("pl"&i),,kouka
      if bac is "1" then --後退
        put line i of gLocs into cLoc
        if abs((item 1 of cloc)-(item 1 of plLoc)) >= abs((item 2 of cloc)-(item 2 of plLoc)) then
          put ((item 1 of cloc)+((item 1 of cloc)-(item 1 of plLoc))/abs((item 1 of cloc)-(item 1 of plLoc))) into mx
          if therepl(mx,item 2 of cloc) is empty then
            setplto mx,item 2 of cloc,i
            if char mx of line (item 2 of cloc) of cd fld "Map" is "c" then Die ("pl"&i)
          end if
        else if abs((item 1 of cloc)-(item 1 of plLoc)) < abs((item 2 of cloc)-(item 2 of plLoc)) then
          put ((item 2 of cloc)+((item 2 of cloc)-(item 2 of plLoc))/abs((item 2 of cloc)-(item 2 of plLoc))) into my
          if therepl(item 1 of cloc,my) is empty then
            setplto item 1 of cloc,my,i
            if char (item 1 of cloc) of line my of cd fld "Map" is "c" then Die ("pl"&i)
          end if
        end if
      end if
    end repeat
    repeat with j=1 to (number of lines of AtkedChar)
      put line j of AtkedChar into i
      if sta is not empty then --スタン
        put icon of cd btn ("pl"&i) into ddIcon
        set icon of cd btn ("pl"&i) to ((char 1 to 2 of ddIcon)&"50")
      end if
      if dam is not 0 then --ダメージ
        if item 1 of cd btn ("pl"&i) is in Str then
          ToHP -2*dam,("pl"&i)
        else ToHP -dam,("pl"&i)
      end if
    end repeat
    put empty into AtkedChar
    --ガソリンスタンドちぇっく
    if mus is not empty and bac is 1 then
      repeat until gGas is empty
        put gGas into GasLoc
        put empty into gGas
        repeat with i=1 to number of lines of GasLoc
          if char (item 1 of line i of GasLoc) of line (item 2 of line i of GasLoc) of cd fld "Map" is "e" then
            play stop
            play "Hit" 24w
            put "a" into char (item 1 of line i of GasLoc) of line (item 2 of line i of GasLoc) of cd fld "Map"
            dispAtackArea (item 1 of line i of GasLoc),(item 2 of line i of GasLoc),3
            put cd fld "cover" into CM
            repeat with i=1 to 10
              if item 2 of cd btn ("pl"&i) is not 0 then
                put line i of gLocs into cLoc
                if char (item 1 of cLoc) of line (item 2 of cLoc) of CM is "a" then
                  put (i) into line (number of lines of AtkedChar)+1 of AtkedChar
                end if
              end if
            end repeat
          end if
        end repeat
      end repeat
    end if
    --ガソリンスタンド爆発
    if AtkedChar is not empty then
      put "Hit" into Res
      repeat with j=1 to (number of lines of AtkedChar)
        put line j of AtkedChar into i
        if item 2 of cd btn ("pl"&i) is not 0 then
          Damdisp ("pl"&i)
          ToHP -5,("pl"&i)
        end if
      end repeat
    end if
    --
    CheckST
  end if
  hidecover
end PlugAtk

on ChariAtack2 what,dam,ran,kouka --種類、ダメージ、無差別？、効果音
  global gBn,gGas
  put cd fld "Map" into CM2
  put cd fld "coverdata" into cd fld "Cover"
  put char 3 of icon of cd btn gBn into plin
  put LocToCharLoc((item 1 of loc of cd btn gBn),(item 2 of loc of cd btn gBn)) into cLoc
  put 0 into x
  put 0 into y
  put item 1 of cloc into cx
  put item 2 of cloc into cy
  if plin is 1 then put 1 into y
  else if plin is 2 then put -1 into x
  else if plin is 3 then put -1 into y
  else if plin is 4 then put 1 into x
  repeat
    add x to cx
    add y to cy
    if cx >=1 and cx <= 13 then
      if cy >=1 and cy <= 6 then
        put "a" into char cx of line cy of cd fld "Cover"
        if char cx of line cy of CM2 is "e" then
          put cx&","&cy into line (number of lines of gGas)+1 of gGas
        end if
      else exit repeat
    else exit repeat
  end repeat
  if what is not empty then
    dispAtackArea (item 1 of cloc),(item 2 of cloc),2,ER
  end if
  show cd fld "Cover"
  PlugAtk dam,1,1,"",ran,"disp",,,kouka,
end ChariAtack2