H            Y/                                    1
     H*---------------------------------------------------------------*
     H* PROGRAM-ID    :    DBTOCSVL
     H* REMARKS       :    CSV LENGTH算出
     H* AUTHOR        :    Y.IDE
     H* DATE-WRITEN   :    2000/7/11
     H* VERSION       :    01.00 ORIGINAL
     H*               :    01.01 エラーコードパラメーター修正
     H*---------------------------------------------------------------*
     FDSPFFDF IF  E                    DISK
     IMASKDS      DS
     I                                        1 256 MASK
     I                                    B 257 2600MSKLEN
     I                                    B 261 2640RCVLEN
     I                                      265 265 ZB
     I                                      266 266 EDTCDE
     I                                      267 267 FI
     I                                    B 268 2710DECLEN
     I                                    B 272 2750DECPOS
     IERROR       DS
     I*                                             Qus EC
     I                                    B   1   40QUSBNB
     I*                                             Bytes Provided
     I                                    B   5   80QUSBNC
     I*                                             Bytes Available
     I                                        9  15 QUSBND
     I*                                             Exception Id
     I                                       16  16 QUSBNF
     I*                                             Reserved
     I*                                      17  17 QUSBNG
     C*
     C           *ENTRY    PLIST
     C                     PARM           RECLEN 150
     C                     Z-ADD0         RECLEN
     C*
     C                     Z-ADD0         QUSBNB
     C*
     C           1         DO   *HIVAL    X       50
     C                     READ DSPFFDF                  98
     C   98                LEAVE
     C*
     C           WHFLDT    IFEQ 'P'
     C           WHFLDT    OREQ 'S'
     C           WHFLDT    OREQ 'B'
     C                     MOVEL' '       ZB
     C                     MOVEL'P'       EDTCDE
     C                     MOVEL' '       FI
     C                     Z-ADDWHFLDD    DECLEN
     C                     Z-ADDWHFLDP    DECPOS
     C                     Z-ADD0         RCVLEN
     C*
     C           WHFLDT    IFEQ 'B'
     C           WHFLDB    IFLE 2
     C                     Z-ADD5         DECLEN
     C                     Z-ADD0         DECPOS
     C                     ELSE
     C                     Z-ADD10        DECLEN
     C                     Z-ADD0         DECPOS
     C                     ENDIF
     C                     ENDIF
     C*
     C                     CALL 'QECCVTEC'
     C                     PARM           MASK             CHAR(32)OUT
     C                     PARM           MSKLEN           BIN(4)  OUT
     C                     PARM           RCVLEN           BIN(4)  OUT
     C                     PARM           ZB               CHAR(1) OUT
     C                     PARM           EDTCDE           CHAR(1)  IN
     C                     PARM           FI               CHAR(1)  IN
     C                     PARM           DECLEN           BIN(4)   IN
     C                     PARM           DECPOS           BIN(4)   IN
     C                     PARM           ERROR            CHAR(*)IN/OU
     C           RECLEN    ADD  RCVLEN    RECLEN
     C                     ELSE
     C*
     C           WHFLDT    IFNE 'F'
     C           RECLEN    ADD  WHFLDB    RECLEN
     C                     ENDIF
     C*
     C           WHFLDT    IFEQ 'G'
     C           RECLEN    ADD  2         RECLEN
     C                     ENDIF
     C           RECLEN    ADD  2         RECLEN
     C*
     C                     ENDIF
     C           RECLEN    ADD  1         RECLEN
     C                     ENDDO
     C           RECLEN    SUB  1         RECLEN
     C                     SETON                     LR
     C                     RETRN