H            Y/                                    1
     H*---------------------------------------------------------------*
     H* PROGRAM-ID    :    DBTOCSVR
     H* REMARKS       :    CSVファイル作成
     H* AUTHOR        :    Y.IDE
     H* DATE-WRITEN   :    2000/7/11
     H* VERSION       :    01.00 ORIGINAL                             *
     H*               :    01.01 エラーコードパラメーター修正
     H*---------------------------------------------------------------*
     FDSPFFDF IF  E                    DISK
     FINPUT   IF  F    9999            DISK
     FOUTPUT  O   F    9999            DISK
     E                    IN       9999  1
     E                    OUT      9999  1
     E                    FDB      9999  5 0
     E                    FDT      9999  1
     IINPUT   AA  01
     I                                        19999 IN
     IMASKDS      DS                       9999
     I                                        1 256 MASK
     I                                    B 257 2600MSKLEN
     I                                    B 261 2640RCVLEN
     I                                      265 265 ZB
     I                                      266 266 EDTCDE
     I                                      267 267 FI
     I                                    B 268 2710DECLEN
     I                                    B 272 2750DECPOS
     IERROR       DS
     I*                                             Qus EC
     I                                    B   1   40QUSBNB
     I*                                             Bytes Provided
     I                                    B   5   80QUSBNC
     I*                                             Bytes Available
     I                                        9  15 QUSBND
     I*                                             Exception Id
     I                                       16  16 QUSBNF
     I*                                             Reserved
     I*                                      17  17 QUSBNG
     C*
     C                     EXSR R#INT
     C*
     C           *IN99     DOUEQ'1'
     C                     READ INPUT                    99
     C   99                LEAVE
     C                     EXSR R#CVT
     C                     EXCPTE#OUT
     C                     ENDDO
     C*
     C                     SETON                     LR
     C                     RETRN
     C*-----------------------------------------------*
     C           R#INT     BEGSR
     C*-----------------------------------------------*
     C*
     C                     Z-ADD0         QUSBNB
     C*
     C                     MOVE X'0E'   OE      1
     C                     MOVE X'0F'   OF      1
     C*
     C           1         DO   *HIVAL    X       50
     C                     READ DSPFFDF                  98
     C   98                LEAVE
     C*
     C                     MOVE WHFLDB    FDB,X
     C                     MOVE WHFLDT    FDT,X
     C*
     C           WHFLDT    IFEQ 'P'
     C           WHFLDT    OREQ 'S'
     C           WHFLDT    OREQ 'B'
     C           X         OCUR MASKDS
     C                     MOVEL' '       ZB
     C                     MOVEL'P'       EDTCDE
     C                     MOVEL' '       FI
     C                     Z-ADDWHFLDD    DECLEN
     C                     Z-ADDWHFLDP    DECPOS
     C                     Z-ADD0         RCVLEN
     C*
     C           WHFLDT    IFEQ 'B'
     C           WHFLDB    IFLE 2
     C                     Z-ADD5         DECLEN
     C                     Z-ADD0         DECPOS
     C                     ELSE
     C                     Z-ADD10        DECLEN
     C                     Z-ADD0         DECPOS
     C                     ENDIF
     C                     ENDIF
     C*
     C                     CALL 'QECCVTEC'
     C                     PARM           MASK             CHAR(32)OUT
     C                     PARM           MSKLEN           BIN(4)  OUT
     C                     PARM           RCVLEN           BIN(4)  OUT
     C                     PARM           ZB               CHAR(1) OUT
     C                     PARM           EDTCDE           CHAR(1)  IN
     C                     PARM           FI               CHAR(1)  IN
     C                     PARM           DECLEN           BIN(4)   IN
     C                     PARM           DECPOS           BIN(4)   IN
     C                     PARM           ERROR            CHAR(*)IN/OU
     C                     ENDIF
     C                     ENDDO
     C           X         SUB  1         X
     C                     ENDSR
     C*-----------------------------------------------*
     C           R#CVT     BEGSR
     C*-----------------------------------------------*
     C                     Z-ADD1         Y1      50
     C                     Z-ADD1         Y2      50
     C                     MOVE *BLANK    OUT
     C           1         DO   X         Y       50
     C                     SELEC
     C* BINARY
     C           FDT,Y     WHEQ 'B'
     C                     MOVEL'*BINARY 'TYPE   10
     C           Y         OCUR MASKDS
     C                     EXSR R#EDT
     C* PACK
     C           FDT,Y     WHEQ 'P'
     C                     MOVEL'*PACKED 'TYPE
     C           Y         OCUR MASKDS
     C                     EXSR R#EDT
     C* FLOAT
     C           FDT,Y     WHEQ 'F'
     C           Y1        ADD  FDB,Y     Y1
     C*
     C           FDT,Y     WHEQ 'S'
     C                     MOVEL'*ZONED  'TYPE
     C           Y         OCUR MASKDS
     C                     EXSR R#EDT
     C*
     C           FDT,Y     WHEQ 'G'
     C                     MOVEA'"'       OUT,Y2
     C           Y2        ADD  1         Y2
     C                     MOVEAOE        OUT,Y2
     C           Y2        ADD  1         Y2
     C                     MOVEAIN,Y1     OUT,Y2
     C           Y1        ADD  FDB,Y     Y1
     C           Y2        ADD  FDB,Y     Y2
     C                     MOVEAOF        OUT,Y2
     C           Y2        ADD  1         Y2
     C                     MOVEA'"'       OUT,Y2
     C           Y2        ADD  1         Y2
     C*
     C                     OTHER
     C                     MOVEA'"'       OUT,Y2
     C           Y2        ADD  1         Y2
     C                     MOVEAIN,Y1     OUT,Y2
     C           Y1        ADD  FDB,Y     Y1
     C           Y2        ADD  FDB,Y     Y2
     C                     MOVEA'"'       OUT,Y2
     C           Y2        ADD  1         Y2
     C                     ENDSL
     C*
     C           Y         IFGE 1
     C           Y         ANDLTX
     C                     MOVEA','       OUT,Y2
     C           Y2        ADD  1         Y2
     C                     ENDIF
     C*
     C                     ENDDO
     C*
     C                     ENDSR
     C*-----------------------------------------------*
     C           R#EDT     BEGSR
     C*-----------------------------------------------*
     C                     CALL 'QECEDT'
     C                     PARM           OUT,Y2
     C                     PARM           RCVLEN           BIN(4)   IN
     C                     PARM           IN,Y1            PACK     IN
     C                     PARM           TYPE             CHAR(10) IN
     C                     PARM           DECLEN           CHAR(1)  IN
     C                     PARM           MASK             CHAR(256)IN
     C                     PARM           MSKLEN           BIN(4)   IN
     C                     PARM           ZB               CHAR(1)  IN
     C                     PARM           ERROR            CHAR(*)IN/OU
     C*
     C           Y1        ADD  FDB,Y     Y1
     C           Y2        ADD  RCVLEN    Y2
     C*
     C                     ENDSR
     O*-----------------*
     OOUTPUT  E                E#OUT
     O                         OUT     9999