/* undsms.cmd ... 「ですます」調のメッセージ・ボックスをマイルドに装飾:-) */
if IsMessageBox() then call MessageFilter
exit 0


/* 現在のメイン・ウィンドウがメッセージボックスかどうかチェックする */
IsMessageBox: procedure
	if ArxQueryWindowInfo('CLIENT','dummy') then return 0
	drop dummy.

	call ArxEnumWindowHandle 'MAIN','hwnd'
	if hwnd.0=0 then return 0

	existcaption = 0 /* キャプションの有無 */
	existmessage = 0 /* メッセージの有無 */
	existsysicon = 0 /* システムアイコンの有無 */
	existbutton = 0  /* ボタンの数 */

	do li = 1 to hwnd.0
		if \ArxQueryWindowInfo('HWND:'hwnd.li,'info') then leave
		id = X2D(SUBSTR(info.ID,2))
		select
		when id=32771/*FID_TITLEBAR*/ then do
			if info.CLASS='#9'/*WC_TITLEBAR*/ then do
				existcaption = 1
			end
		end
		when id=400 then do
			if info.CLASS='#5'/*WC_STATIC*/ then do
				if X2D(RIGHT(info.STYLE,1))=1/*SS_TEXT*/ then do
					existcaption = 1
				end
			end
		end
		when id=300 then do
			if info.CLASS='#5'/*WC_STATIC*/ then do
				if X2D(RIGHT(info.STYLE,1))=11/*SS_SYSICON*/ then do
					existsysicon = 1
				end
			end
		end
		when id=200 then do
			if info.CLASS='#5'/*WC_STATIC*/ then do
				if X2D(RIGHT(info.STYLE,1))=1/*SS_TEXT*/ then do
					existmessage = 1
				end
			end
		end
		when (id>=1 & id<=9) | (id>=101 & id<=103) then do
			if info.CLASS='#3'/*WC_BUTTON*/ then do
				existbutton = existbutton + 1
			end
		end
		when id=32770/*FID_SYSMENU*/ | id=32772/*FID_MINMAX*/ then do
			if info.CLASS='#4'/*WC_MENU*/ then do
				nop
			end
			else leave
		end
		otherwise
			leave
		end
	end

	if \existcaption | \existmessage | \existsysicon | existbutton\=4 then do
		return 0
	end
return 1


/* メッセージ文字列を変換する */
MessageFilter: procedure
	if \ArxQueryWindowString(200,'str') then return
	options exmode

	li = 1
	do forever
		len = length(str)
		if len<li then leave
		sst.1 = substr(str,li,1)
		if len-li<1 then sst.2 = sst.1; else sst.2 = substr(str,li,2)
		if len-li<2 then sst.3 = sst.2; else sst.3 = substr(str,li,3)
		if len-li<3 then sst.4 = sst.3; else sst.4 = substr(str,li,4)
		if len-li<4 then sst.5 = sst.4; else sst.5 = substr(str,li,5)

		if \FilterSub('でした','でしてん') then
		if \FilterSub('ました','ましてん') then
		if \FilterSub('です','でっせ') then
		if \FilterSub('ます','まっせ') then
		if \FilterSub('ですか','でっか') then
		if \FilterSub('ますか','まっか') then
		if \FilterSub('ですが','でんが') then
		if \FilterSub('ますが','まんが') then
		if \FilterSub('ですけど','でっけど') then
		if \FilterSub('ますけど','まっけど') then
		if \FilterSub('ません','まへん') then
		nop

		li = li + 1
	end

	options noexmode
	call ArxSetWindowString 200,str
return


/* 文字列置換用サブルーチン */
/* 引数：置換前文字列 , 置換後文字列 */
FilterSub: procedure expose str li sst.
	parse arg src,dst

	sl = length(src)
	tl = sl + 1
	dl = length(src)

	if sst.sl=src then do
		ignore = 0
		if sst.sl\=sst.tl then do
			c = substr(sst.tl,tl)
			if verify(c,'!.?｡､、。，．？！')\=0 then do
				ignore = 1
			end
		end
		if \ignore then do
			str = insert(dst,delstr(str,li,sl),li-1)
			li = li + length(dst)
			return 1
		end
	end
return 0