/* IBM-Works を PIM のみ残して除去する。 */
OPTIONS EXMODE
CALL RxFuncAdd "SysLoadFuncs", "RexxUtil", "SysLoadFuncs"
CALL SysLoadFuncs

WorksDir = VALUE("IBMWORKS_INI",,"OS2ENVIRONMENT")
IF WorksDir="" THEN DO
	SAY "IBM-Works のディレクトリが見つかりません。"
	EXIT 1
END

PimFile.0  = 10
PimFile.1  = TRANSLATE(WorksDir"\CRT.DLL")
PimFile.2  = TRANSLATE(WorksDir"\IJP30PAR.DLL")
PimFile.3  = TRANSLATE(WorksDir"\IJP30PXR.DLL")
PimFile.4  = TRANSLATE(WorksDir"\IJP30PXU.DLL")
PimFile.5  = TRANSLATE(WorksDir"\PIMRL.DLL")
PimFile.6  = TRANSLATE(WorksDir"\FPWMON.EXE")
PimFile.7  = TRANSLATE(WorksDir"\FPWPIM.EXE")
PimFile.8  = TRANSLATE(WorksDir"\FPWPIM.HLP")
PimFile.9  = TRANSLATE(WorksDir"\FPWPIM.INI")
PimFile.10 = TRANSLATE(WorksDir"\IBMWORKS.INI")
PimDataDir = TRANSLATE(WorksDir"\DATA\")

SAY "警告："
SAY "　このスクリプトは、IBM-Works を PIM のみ残して除去します。"
SAY "　実行中の IBM-Works がある場合は、終了させて下さい。"
"@PAUSE"

SAY "Workplace Object を削除しています..."
CALL SysDestroyObject "<WP_FPWO_WPTEMP>"
CALL SysDestroyObject "<WP_FPWO_SSTEMP>"
CALL SysDestroyObject "<WP_FPWO_CHTEMP>"
CALL SysDestroyObject "<WP_FPWO_DBTEMP>"
CALL SysDestroyObject "<WP_FPWO_RWTEMP>"
CALL SysDestroyObject "<WP_FPWO_GRTEMP>"

CALL SysDestroyObject "<WP_FPWO_EXE>"
CALL SysDestroyObject "<WP_FPWO_README>"
CALL SysDestroyObject "<WP_FPWO_SAMP_FOLD>"
CALL SysDestroyObject "<FPW_CATALYST>"

SAY "Workplace Object クラスを登録解除しています..."
CALL SysDeregisterObjectClass "FpwCatalyst"
CALL SysDeregisterObjectClass "FpwWPSData"
CALL SysDeregisterObjectClass "FpwWPData"
CALL SysDeregisterObjectClass "FpwSSData"
CALL SysDeregisterObjectClass "FpwCHData"
CALL SysDeregisterObjectClass "FpwDBData"
CALL SysDeregisterObjectClass "FpwRWData"
CALL SysDeregisterObjectClass "FpwGRData"

SAY "ファイルを削除しています..."
CALL SysFileTree WorksDir"\*" ,"Files" ,"FOS"
IF Files.0>0 THEN DO
	DO li = 1 TO Files.0
		Files.li = TRANSLATE(Files.li)
		DO lj = 1 TO PimFile.0
			IF Files.li=PimFile.lj THEN ITERATE li
		END
		IF POS(PimDataDir,Files.li)=1 THEN ITERATE li
		IF SysFileDelete(Files.li)\=0 THEN SAY "消去失敗:"Files.li
	END
END

SAY ""
SAY "終了しました。"
"@PAUSE"

EXIT 0