動画ファイル（アニメーションGIF）の作り方

連続した画像をファイルに書き出して， フリーソフトのGIAMを使ってアニメーションGIFを作ることができます。
作成したGIFアニメーションは，インターネットのWebページやPowerPointなどで使うことができます（十進BASICでは使えません）。
リンク先にGIAMで作成したアニメーションGIFのサンプルを用意します （アニメーションGIFサンプル）。 

100 OPTION ARITHMETIC NATIVE
110 OPTION ANGLE DEGREES
120 PICTURE tragon(n,red,green,blue)
130    IF n=depth THEN
140       SET COLOR MIX (1) red,green,blue
150       PLOT POINTS: 0,0
160    ELSE
170       DRAW tragon(n+1,red+2^(-n),green,blue) WITH SCALE(1/SQR(3))*ROTATE(alpha) 
180       DRAW tragon(n+1,red,green+2^(-n),blue) WITH SHIFT(-2,0)*SCALE(1/SQR(3))*ROTATE(alpha)*SHIFT(2,0)
190       DRAW tragon(n+1,red,green,blue+2^(-n)) WITH SHIFT(-1,-SQR(3))*SCALE(1/SQR(3))*ROTATE(alpha)*SHIFT(1,SQR(3))
200    END IF
210 END PICTURE
220 SET POINT STYLE 1
230 SET POINT COLOR 1
240 SET WINDOW -3,5,-3,5
250 ASK PIXEL SIZE(-3,-3;5,5) px,py
260 LET depth=CEIL(-LOG(px-1)/LOG(1/SQR(3)))
270 LET alpha=0
280 LET count=0
290 DO UNTIL alpha=360
300    SET DRAW mode hidden
310    CLEAR 
320    DRAW tragon(1,0,0,0)
330    SET DRAW mode explicit
340    LET count=count+1
350    GSAVE "F:\TEMP\tri" & USING$("%%%%%",count) & ".GIF"
360    LET alpha=alpha+1
370 LOOP
380 END

プログラムの説明
一コマ分の画像を描くごとに350行のGSVEで画像をファイルに保存します。
ファイル名には一連番号を付与するのが便利なので，一コマ保存するたびに番号を１だけ増やします（340行，280行で初期設定）。
保存先のファイルは自動で作成されますが，フォルダはあらかじめ用意してください。
たとえば，350行のようにGSAVEを使う場合，あらかじめ，Fドライブに，TEMP というフォルダを用意しておきます。

戻る