@echo off
setlocal

echo;
echo  [ 録画済み番組リストの取得・保存 ]   - Version 1.0.0.0

rem ------------------------- ↓ @以下を書き換えて下さい。↓ -------------------------
set diga=@対象のDIGAの登録名称を指定します。[必須]
set folder=@ファイルを保存するフォルダを指定します。[既定: .\\RecordList]
set name=@保存するファイルの名称を指定します。[既定: Auto]
set type=@保存するファイルの種類を指定します。[既定: CSV]
set header=@ファイルにヘッダを付加するか指定します。[既定: True] ※XML以外
set overwrite=@ファイルが存在する場合、上書きするか指定します。[既定: False]
rem ----------------------------------------------------------------------------------

set default=Default
set flag=false

if "%diga%" equ "" ( set diga=%default%)
if "%folder%" equ "" ( set folder=%default%)
if "%name%" equ "" ( set name=%default%)
if "%type%" equ "" ( set type=%default%)
if "%header%" equ "" ( set header=%default%)
if "%overwrite%" equ "" ( set overwrite=%default%)

if "%diga:@=%" neq "%diga%" ( set flag=true)
if "%folder:@=%" neq "%folder%" ( set flag=true)
if "%name:@=%" neq "%name%" ( set flag=true)
if "%type:@=%" neq "%type%" ( set flag=true)
if "%header:@=%" neq "%header%" ( set flag=true)
if "%overwrite:@=%" neq "%overwrite%" ( set flag=true)

if "%flag%" equ "true" (
 echo;
 echo;
 echo ------------------------------------------------------------------------------------------------------------------------
 echo DIGA録画予約アプリのパラメータを取得します。
 echo ========================================================================================================================
)

if "%diga:@=%" neq "%diga%" ( set /p diga=%diga:@=% :)
if "%folder:@=%" neq "%folder%" ( set /p folder=%folder:@=% :)
if "%name:@=%" neq "%name%" ( set /p name=%name:@=% :)
if "%type:@=%" neq "%type%" ( set /p type=%type:@=% :)

for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) ^
do call set name=%%name:%%i=%%i%%

for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) ^
do call  set type=%%type:%%i=%%i%%

if "%type%" neq "xml" (
   if "%header:@=%" neq "%header%" ( set /p header=%header:@=% :)
)
if "%name%" neq "" ( if "%name%" neq "auto" (
   if "%overwrite:@=%" neq "%overwrite%" ( set /p overwrite=%overwrite:@=% :)
))


if "%flag%" equ "true" (
 echo ------------------------------------------------------------------------------------------------------------------------
 echo 次回からバッチファイルにパラーメータを記入する事で自動実行する事が出来ます。
 echo;
)

if "%diga:"=%" equ "" ( set diga=%default%)
if "%folder:"=%" equ "" ( set folder=%default%)
if "%name:"=%" equ "" ( set name=%default%)
if "%type:"=%" equ "" ( set type=%default%)
if "%header:"=%" equ "" ( set header=%default%)
if "%overwrite:"=%" equ "" ( set overwrite=%default%)

if "%diga:@=%" neq "%diga%" ( set diga=%default%)
if "%folder:@=%" neq "%folder%" ( set folder=%default%)
if "%name:@=%" neq "%name%" ( set name=%default%)
if "%type:@=%" neq "%type%" ( set type=%default%)
if "%header:@=%" neq "%header%" ( set header=%default%)
if "%overwrite:@=%" neq "%overwrite%" ( set overwrite=%default%)

set param=-diga "%diga:"=%"
if "%folder:"=%" neq "" ( if "%folder%" neq "%default%" ( set param=%param% -folder "%folder:"=%"))
if "%name:"=%" neq "" ( if "%name:"=%" neq "%default%" ( set param=%param% -name "%name:"=%"))
if "%type:"=%" neq "" ( if "%type:"=%" neq "%default%" ( set param=%param% -type "%type:"=%"))
if "%header:"=%" neq "" ( if "%header:"=%" neq "%default%" ( set param=%param% -header "%header:"=%"))
if "%overwrite:"=%" neq "" ( if "%overwrite:"=%" neq "%default%" ( set param=%param% -overwrite "%overwrite:"=%"))

echo Parameter : %param%
echo;

DIGA録画予約アプリ.exe %param%
echo ========================================================================================================================

timeout /t 2
endlocal